DE  |  FR

Audio-CDs im Stapelverfahren umwandeln

Zur Archivierung muss der Datenstrom auf Audio-CDs mit einem Ripper-Programm in Dateien umgewandelt werden. Diese Umwandlung kann bei einer grösseren Menge von CDs eine geraume Zeit in Anspruch nehmen und einen nicht zu unterschätzenden 'handling' Aufwand verursachen. Der Prozess muss sinnvollerweise automatisiert werden.

 

1.   CD-Rippen

2.   Mehrere CDs gleichzeitig lesen

3.   Rippen mit Exact Audio Copy

4.   Batch Datei für Exact Audio Copy

5.   Source Code und Programme

6.   Weiterführende Links

7.   Anhang

1.       CD-Rippen

Für die Umwandlung eines Audiodatenstroms in eine Audiodatei wird ein Programm vom Typ CD-Ripper benötigt. Das Rippen (umwandeln in WAV Dateien) kann pro CD bis zu einer Stunde dauern. Zum Glück oder eben darum können etliche dieser Programme auch im Batch Mode[i] arbeiten, sodass der Prozess automatisiert werden kann.

2.       Mehrere CDs gleichzeitig lesen

Damit sich der Vorgang des CD-Rippens sinnvoll automatisieren lässt, ist die wichtigste Grundvoraussetzung, dass mehrer CDs auf einmal eingelegt und anschliessend der Rippvorgang für alle CDs gestartet werden kann. Da heute praktische keine Computer über mehr als ein CD-Laufwerk verfügen und so genannte CD-Changer (CD-Wechsler) kaum mehr in Gebrauch sind, muss als erstes dafür ein Weg gefunden werden.

Home built CD changer / duplicator[ii]

a)       CD-Laufwerke im Netzwerk

Mehrere CD-Laufwerke könnten im Netzwerk freigegeben werden, was aber den Nachteil hat, dass die Laufwerke nicht am gleichen Ort sein müssen und nicht in einem Arbeitsgang geladen werden können.

b)       USB CD-Laufwerke

Besser ist es, mehrere USB-CD-Laufwerke via USB-Hub an den gleichen Rechner anzuschliessen (maximal 127). Hier ein günstiges Beispiel, €12.50:

NEC CD-2800E CD-ROM Reader USB

3.       Rippen mit Exact Audio Copy

Wir zeigen das Automatisieren des Vorganges anhand von EAC. Exact Audio Copy (EAC) ist Freeware und kann von http://www.exactaudiocopy.de/ heruntergeladen werden. (Das Programm liegt zurzeit in V0.99 prebeta 4 vor.) Die .exe-Datei wird nach dem Download mittels Doppelklick installiert. Anschliessend müssen einige Konfigurationen vorgenommen werden, siehe dazu KOST.services Archivierung mediengebundener Formate[iii].

Zusätzlich muss vor der Anwendung im Batchmode das Ausgabeverzeichnis, worin die Audiodateien erstellt werden sollen angelegt und konfiguriert werden (EAC options / F9).

EAC options: Standard directory for extraction

Das Namensschema für die Ausgabedateien kann ebenfalls festgelegt werden.

EAC options: Filename

Das Programm wird anschliessend im Windows CMD Fenster folgendermassen aufgerufen:

  EAC.EXE -EXTRACTWAV -DRIVE # -CLOSE

Das erste CD Laufwerk am Rechner erhält die Nummer -DRIVE 0, die weiteren Laufwerke sind aufsteigend nummeriert. Die Nummerierung folgt den zugeordneten Laufwerkbuchstaben. Bei der Verwendung von USB CD-Laufwerken ergibt sich die Nummerierung durch die Reihenfolge in der die Laufwerke dem Rechner bekannt gemacht wurden / eingesteckt worden sind.

Der Befehl oben extrahiert die CD im gewählten Laufwerk in das voreingestellte Ausgabeverzeichnis mit der festgelegten Namensgebung pro Track. In einem einfachen Loop über alle Laufwerke können so die Daten von mehreren CD-Laufwerken gelesen werden. Weil die Audio Tracks einer CD alle in das gleiche Ausgabeverzeichnis kopiert werden, müssen diese Dateien am Schluss einer CD Verarbeitung in ein anderes Verzeichnis verschoben werden.

EAC erlaubt die Verwendung weiterer Command-Line Optionen, siehe dazu die weiterführenden Links.

4.       Batch Datei für Exact Audio Copy

Im Anhang wird gezeigt, wie eine Batch Datei aufgebaut sein kann. Zuerst wird der Installationspfad von EAC ermittelt, dann das Ausgabeverzeichnis von EAC aus der Windows Registry ausgelesen, zwei Hilfsprogramme, grep.exe und cut.exe sind dazu notwendig. Anschliessend wird für jedes Argument zu extract-multi-cds.bat eine CD beginnend mit dem ersten CD Laufwerk am Rechner extrahiert.

In unserem Beispiel (oben) wird also mit extract-multi-cds.bat CD1 CD2 CD3 die Audio Tracks von drei CD Laufwerken in die folgenden Verzeichnisse ausgelesen:

C:\CDProject\audiodata\CD1  ..\CD2  ..\CD3

5.       Source Code und Programme

Der Source Code im Anhang steht auch auf der KOST Website zum Download bereit, ebenso die Hilfsprogramme grep.exe und cut.exe. Bitte beachten sie die Copyright Bedingungen zu diesen Programmen:

cut.exe --v
Copyright (C) 1988, 1992-1998, 1999 Free Software Foundation, Inc.

This is free software; see the source for copying conditions. There is NO warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

6.       Weiterführende Links

7.       Anhang

:: Batch file: extract-multi-cds.bat
@ECHO OFF

:: Keep variables local
SETLOCAL

:: Remove temporary files
IF EXIST "%temp%\~eacreg.tmp" DEL "%temp%\~eacreg.tmp"
IF EXIST "%temp%\~eacdirspec.tmp" DEL "%temp%\~eacdirspec.tmp"

:: read registry entry for EAC
REGEDIT.EXE /E "%temp%\~eacreg.tmp" "HKEY_CURRENT_USER\Software\AWSoftware\EAC"

:: extract EAC InstallPath
TYPE "%temp%\~eacreg.tmp" | GREP "InstallPath" | CUT -b 16- > "%temp%\eacinstallpath.tmp"
FOR /F "delims= tokens=1" %%d IN ('TYPE %temp%\eacinstallpath.tmp') DO SET _installpath=%%d
SET _installpath=%_installpath:"=%
SET _installpath=%_installpath:\\=\%

:: extract EAC DirectorySpecification
TYPE "%temp%\~eacreg.tmp" | GREP "DirectorySpecification" | CUT -b 26- > "%temp%\~eacdirspec.tmp"
FOR /F "delims= tokens=1" %%d IN ('TYPE %temp%\~eacdirspec.tmp') DO SET _dirspec=%%d
SET _dirspec=%_dirspec:"=%
SET _dirspec=%_dirspec:\\=\%
SET /A _driveno=0

:Loop
IF "%1"=="" GOTO Continue
  
ECHO .
   ECHO Process: %1 in drive %_driveno% -^> %_dirspec%%1
   "%_installpath%/EAC.EXE" -EXTRACTWAV -DRIVE %_driveno% -CLOSE
   IF NOT EXIST "%_dirspec%\%1" MKDIR "%_dirspec%\%1"
   IF EXIST "%_dirspec%\*.WAV" MOVE "%_dirspec%\*.WAV" "%_dirspec%\%1"
   SET /A _driveno+=1
SHIFT
GOTO Loop

:Continue


[i] Siehe dazu Wikipedia Stapelverarbeitung: http://de.wikipedia.org/wiki/Stapelverarbeitung

Diese Handreichung als PDF-Datei downloaden

Audio-CDs_im_Stapelverfahren_in_Dateien_umwandeln_v2.pdf, 129K, 20.07.10
Audio-CDs im Stapelverfahren in Dateien umwandeln

cut.exe, 23.5K, 20.07.10
Bitte beachten sie die Copyright Bedingungen zu diesem Programm

grep.exe, 81K, 20.07.10
Bitte beachten sie die Copyright Bedingungen zu diesem Programm